[Remind-Fans] Remind 3.1.0 BETA 2 is available

[Davide Alberani]

On Jul 17, "David F. Skoll" <dfs at roaringpenguin.com> wrote:

> Remind 03.01.00 BETA 2 is available at:

So cool! :-)

In the attachment there's the latest remind.vim, syntax file for
the VIM editor.
I've added highlighting for the "FROM" clause and for the TIME,
DATE and DATETIME data types.

I'm still undecided about colors and other minor changes, so
feel free to submit any hint. :-)


-- 
Davide Alberani <alberanid at libero.it> [PGP KeyID: 0x465BFD47]
http://erlug.linux.it/~da/
-------------- next part --------------
" Vim syntax file
" Language:	Remind
" Maintainer:	Davide Alberani <alberanid at libero.it>
" Last Change:	25 Jun 2007
" Version:	0.4
" URL:		http://erlug.linux.it/~da/vim/syntax/remind.vim
"
" remind is a sophisticated reminder service
" you can download remind from:
"   http://www.roaringpenguin.com/penguin/open_source_remind.php

if version < 600
  syntax clear
elseif exists("b:current_syntax")
  finish
endif

" shut case off
syn case ignore

syn keyword remindCommands	REM OMIT SET FSET UNSET
syn keyword remindExpiry	UNTIL FROM SCANFROM SCAN WARN SCHED
syn keyword remindTag		PRIORITY TAG
syn keyword remindTimed		AT DURATION
syn keyword remindMove		ONCE SKIP BEFORE AFTER
syn keyword remindSpecial	INCLUDE INC BANNER PUSH-OMIT-CONTEXT PUSH CLEAR-OMIT-CONTEXT CLEAR POP-OMIT-CONTEXT POP COLOR
syn keyword remindRun		MSG MSF RUN CAL SATISFY SPECIAL PS PSFILE SHADE MOON
syn keyword remindConditional	IF ELSE ENDIF IFTRIG
syn keyword remindDebug		DEBUG DUMPVARS DUMP ERRMSG FLUSH PRESERVE
syn match remindComment		"#.*$"
syn region remindString		start=+'+ end=+'+ skip=+\\\\\|\\'+ oneline
syn region remindString		start=+"+ end=+"+ skip=+\\\\\|\\"+ oneline
syn match remindVar		"\$[_a-zA-Z][_a-zA-Z0-9]*"
syn match remindSubst		"%[^ ]"
syn match remindAdvanceNumber	"\(\*\|+\|-\|++\|--\)[0-9]\+"
" XXX: divide separators used for dates from the ones used by times?
syn match remindDateSeparators	"[/:@\.-]" contained
syn match remindTimes		"[0-9]\{1,2}[:\.][0-9]\{1,2}" contains=remindDateSeparators
" TODO: why not match only valid dates (ok, checking for 02/29 would be
"       impossible, but at least check for valid months and times).
syn match remindDates		"'[0-9]\{4}[/-][0-9]\{1,2}[/-][0-9]\{1,2}\(@[0-9]\{1,2}[:\.][0-9]\{1,2}\)\?'" contains=remindDateSeparators
" This will match trailing whitespaces that seem to broke rem2ps.
" Courtesy of Michael Dunn.
syn match remindWarning		display excludenl "\S\s\+$"ms=s+1


if version >= 508 || !exists("did_remind_syn_inits")
  if version < 508
    let did_remind_syn_inits = 1
    command -nargs=+ HiLink hi link <args>
  else
    command -nargs=+ HiLink hi def link <args>
  endif

  HiLink remindCommands		Function
  HiLink remindExpiry		Repeat
  HiLink remindTag		Label
  HiLink remindTimed		Statement
  HiLink remindMove		Statement
  HiLink remindSpecial		Include
  HiLink remindRun		Function
  HiLink remindConditional	Conditional
  HiLink remindComment		Comment
  HiLink remindDateSeparators	Comment
  HiLink remindDates		String
  HiLink remindTimes		String
  HiLink remindString		String
  HiLink remindDebug		Debug
  HiLink remindVar		Identifier
  HiLink remindSubst		Constant
  HiLink remindAdvanceNumber	Number
  HiLink remindWarning		Error

  delcommand HiLink
endif

let b:current_syntax = "remind"

" vim: ts=8 sw=2